home *** CD-ROM | disk | FTP | other *** search
/ Atari Mega Archive 2 / Atari Mega Archive CD - Volume 2.iso / 8bit / cislib_a / musici.xmo < prev    next >
Text File  |  1995-04-22  |  989b  |  43 lines
  1. 100 REM  Musician  
  2. 110 GRAPHICS 19 
  3. 120 DIM SC(21),MU(1024) 
  4. 130 FOR I=0 TO 21 
  5. 140 READ SC 
  6. 150 SC(I)=SC 
  7. 160 NEXT I 
  8. 170 DATA 243,217,193,182,162,144 
  9. 180 DATA 128,121,108,96,91,81,72 
  10. 190 DATA 64,60,53,47,45,40,35,31,29 
  11. 200 PER=INT(13*RND(0))+3 
  12. 210 PHR=INT(54*RND(0))+10 
  13. 220 FOR I=0 TO PHR 
  14. 230 BASE=INT(15*RND(0)) 
  15. 240 FOR J=0 TO PER 
  16. 250 MU(J+I*PER)=BASE+INT(8*RND(0)) 
  17. 260 NEXT J 
  18. 270 NEXT I 
  19. 280 RPT=INT(3*RND(0))+2 
  20. 290 SPD=0.5+2*RND(0) 
  21. 300 FOR I=0 TO PHR 
  22. 310 IF X0>39-PER THEN X0=0:GRAPHICS 19 
  23. 320 FOR J=0 TO RPT 
  24. 330 FOR K=0 TO PER-1 
  25. 340 X=X0+K:Y=MU(K+I*PER) 
  26. 350 COLOR 1:PLOT X,23-Y 
  27. 360 P=PEEK(53279) 
  28. 370 IF P=6 THEN POP :X0=40:GOTO 300 
  29. 380 IF P=5 THEN RUN  
  30. 390 IF P=3 THEN POP :GOTO 320 
  31. 400 CHAN=INT(RND(0)*4) 
  32. 410 FOR V=15 TO 2 STEP -SPD 
  33. 420 SOUND CHAN,SC(Y),10,V 
  34. 430 NEXT V 
  35. 440 COLOR 3:PLOT X,23-Y 
  36. 450 NEXT K 
  37. 460 NEXT J 
  38. 470 X0=X0+PER+1:POKE 77,0 
  39. 480 NEXT I 
  40. 490 FOR I=0 TO 500:NEXT I 
  41. 500 FOR I=0 TO 3:SOUND I,0,0,0:NEXT I 
  42. 510 X0=0:GRAPHICS 19:GOTO 200 
  43.